// display text, classify emotion, move
// mpurver

import processing.net.*;
import liblinear.*;
import controlP5.*;


ControlP5 controlP5;
String textValue = "";
Textfield myTextfield;

int iSector = 0;
int nSector = 6;
float sectorAngle = TWO_PI / 6.0;
int centreX;
int centreY;
int radius = 150;
color sectorColour = color(50,200,0);
color lineColour = color(100);
color textColour = color(255,255,255);
color sentenceColour = color(255);

BufferedWriter logger;
Calendar calendar = Calendar.getInstance();
SimpleDateFormat sdf = new SimpleDateFormat("yyyy-MM-dd HH:mm:ss");


int pause = 0;
int p = 0;
int waitSpins = 6;
int ws = waitSpins;
boolean running = false;
boolean gotResult = false;
String lastSent = "";
String sent = "";
double[] classes = null;
String[] emotions = new String[] { 
  "happy", "anger", "fear", "sad", "surprise", "disgust"
};
int bg = 0;
Client httpClient;
Classifier svm;
String installDir = "http://www.eecs.qmul.ac.uk/~mpurver/WoE";
//String installDir = "/Users/toby/Desktop/WheelOfEmotion";


void setup() {

  size(600, 400, JAVA2D);
  centreX = width/2;
  centreY = height/2;

  PFont font = createFont("Arial-BoldMT", 24); 
  textFont(font);
  textAlign(CENTER);

  svm = new Classifier(installDir, emotions);

  frameRate(20);
  background(bg);
  stroke(lineColour);
  smooth();

  controlP5 = new ControlP5(this);
  //  controlP5.setControlFont(createFont("Arial-BoldMT",12));
  myTextfield = controlP5.addTextfield("sentence",10,height-50,200,20);
  myTextfield.setFocus(true);
  myTextfield.keepFocus(true);
  
  if (!installDir.startsWith("http:")) {
    try {
      logger = new BufferedWriter( new FileWriter( new File(installDir, "log.txt"), true ) );
      loggit("NEW RUN");
    } catch (Exception e) {
      e.printStackTrace();
      System.exit(0);
    }
  }
  
}

void draw() {
  // are we pausing?
  if (p > 0) {
    p--;
    println("pausing");
    controlP5.draw();
    return;
  }

  // if it's new, classify and start new display
  if (!sent.equals(lastSent)) { 

    println("new sentence");
    loggit("NEW SENTENCE [" + sent + "]");

    running = true;
    gotResult = false;
    // classify
    classes = classify(sent);
    loggit("CLASSES " + Arrays.toString(classes));
    p = pause;
    ws = waitSpins;
  } 
  else {

    //println("old sentence");
  }

  // clear background
  background(bg);
  //text(sent,centreX,centreY);

  // draw circle
  if (!sent.isEmpty()) {
    float startAngle = 0;
    float endAngle = sectorAngle;
    for (int iS = 0; iS<nSector; iS++) {
      fill(getColour(iS),getAlpha(iS));
      //    println(iS + " " + getColour(iS)+" " +getAlpha(iS));
      strokeWeight(10);
      stroke(lineColour);
      arc(centreX,centreY,radius*2,radius*2,startAngle,endAngle);
      fill(textColour);
      text(emotions[iS], centreX + (radius * cos(startAngle+sectorAngle/2)), centreY + (radius * sin(startAngle+sectorAngle/2)));
      fill(sentenceColour,125);
      text(sent,centreX,centreY+10);
      startAngle += sectorAngle;
      endAngle += sectorAngle;
    }

    iSector++;
    if (iSector == nSector) {
      iSector = 0;
      if (ws > 0) {
        ws--;
      }
    }
    lastSent = sent;
  }

  strokeWeight(1);
  controlP5.draw();
}

private int getColour(int iS) {
  if (ws > 0) {
    // waiting to build tension, so just light up current sector ...
    if (iS == iSector) {
      return sectorColour;
    } 
    else {
      return bg;
    }
  } 
  else {
    // we're ready, so display results from classifier
    if (classes[iS]>0) {
      return sectorColour;
    } 
    else {
      return bg;
    }
  }
}

private float getAlpha(int iS) {
  if ((ws > 0) || (classes[iS]<=0)) {
    return 255;
  } 
  else {
    return 255*(float)classes[iS];
  }
}

private boolean fake = false;
private double[] classify(String s) {
  double[] l = new double[emotions.length];
  if (fake) {
    for (int i=0; i<l.length; i++) {
      l[i] = random(-1,1);
    }
  } 
  else {
    l = svm.predict(s);
    // scale if max > 1
    double max = 0.0;
    for (int i=0; i<l.length; i++) {
      max = ( max > l[i] ? max : l[i] );
      println("got data " + emotions[i] + " " + i + " " + l[i]);
    }
    if (max > 1.0) {
      for (int i=0; i<l.length; i++) {
        l[i] = l[i] / max;
        println("scale data " + emotions[i] + " " + i + " " + l[i]);
      }
    }
  }
  println("got classification " + Arrays.toString(l));
  return l;
}


//void controlEvent(ControlEvent theEvent) {
//  println("controlEvent: accessing a string from controller '"+theEvent.controller().name()+"': "+theEvent.controller().stringValue());
//}

public void sentence(String text) {
  // receiving text from sentence controller
  sent = text;
}

public void loggit(String s) {
  if (logger != null) {
    try {
      logger.write(sdf.format(calendar.getTime()) + " " + s + "\n");
      logger.flush();
    } catch (IOException e) {
      e.printStackTrace();
      System.exit(0);
    }
  }
}

// look for a key press to activate cacheing
void keyPressed() {
  if ((key == '1') || (key == '2') || (key == '3') || (key == '4') || (key == '5') || (key == '6')) {
    int iClass = (Integer.parseInt("" + key) - 1);
    println("cache key pressed " + key);
    loggit("ADD CACHE " + iClass + " " + sent);
    for (int i=0; i<classes.length; i++) {
      classes[i] = ( (i==iClass) ? 1.0 : 0.0 );
    }
    svm.addCache(sent,iClass);
    myTextfield.clear();
  }
}